◕ دورة احترافية لربط الإكسل Excel لتحليل البيانات اللحظية والتاريخية ◕ ← إصنع برنامجك

Sub Main()
    'تحديد اتجاه الصفحة من اليمين إلى اليسار (اللهم اجعلنا من أهل اليمين)
    ActiveSheet.DisplayRightToLeft = True
    Cells.Font.Name = "Arial Unicode MS"
    Cells.Font.Size = 10

    'عامود كود السهم
    Columns(1).ColumnWidth = 8                  'سمكه صغير نسبيًا
    Columns(1).HorizontalAlignment = xlCenter   'محاذاة للمنتصف
    Columns(1).Font.Color = vbRed               'اللون الأحمر
    Columns(1).Font.Bold = True                 'الخط الثقيل
    
    'عامود إسم السهم
    Columns(2).ColumnWidth = 25                 'سمكه كبير
    Columns(2).HorizontalAlignment = xlRight    'محاذاة لليمين
    Columns(2).Font.Color = vbBlue              'اللون الأزرق
    Columns(2).Font.Bold = True                 'الخط الثقيل
    
    'عامود مسار ملف الميتاستوك الخاص بالسهم
    Columns(3).ColumnWidth = 80                'سمكه كبير جدًا
    Columns(3).HorizontalAlignment = xlLeft     'محاذاة لليسار
    
    'تلوين صف عناوين الأعمدة
    Rows(1).Interior.Color = RGB(220, 220, 255)
    Rows(1).Font.Bold = True                 'الخط الثقيل
    
    'تحديد أسماء الأعمدة ومحاذتها
    Cells(1, 1) = "الكود"
    Cells(1, 2) = "إسم السهم"
    Cells(1, 2).HorizontalAlignment = xlCenter   'محاذاة للمنتصف
    Cells(1, 3) = "مسار ملف الميتاستوك"
    Cells(1, 3).HorizontalAlignment = xlCenter   'محاذاة للمنتصف

    'مسار المجلد الذي يحتوي على الإي ماستر بجهازك
    Dim path As String
    path = "C:\Users\Tamer\Documents\LiveMetaStock\Daily\Saudi Stock Exchange-Ta\"
    
    'قراءة ملف الإي ماستر وتحويله إلى مصفوفة من البايتس
    Dim bytes() As Byte
    bytes = GetFileBytes(path + "EMASTER")
    
    Dim bytes_code(3) As Byte       'عدد 4 بايت لتخزين كود السهم
    Dim bytes_name(51) As Byte      'عدد 52 بايت لتخزين إسم السهم
    
    'تكرار الأوامر الآتية بعدد الأسهم كلها
    For i = 1 To UBound(bytes) / 192
        'هنا يتم استخراج بيانات السهم
        
        'أولًا كود السهم ويتكون من عدد 4 بايت بداية من البايت رقم 11
        For j = 0 To 3
            bytes_code(j) = bytes(i * 192 + 11 + j)
        Next j
        Cells(i + 1, 1) = StrConv(bytes_code, vbUnicode)
        
        'ثانيًا إسم السهم ويتكون من عدد 52 بايت بداية من البايت رقم 139
        For j = 0 To 51
            bytes_name(j) = bytes(i * 192 + 139 + j)
        Next j
        Cells(i + 1, 2) = StrConv(bytes_name, vbUnicode, &H401)
        
        'ثالثًا رقم ملف الميتاستوك الخاص بالسهم وهو بالبايت رقم 2
        Cells(i + 1, 3) = path + "F" + CStr(bytes(i * 192 + 2)) + ".DAT"
    Next i
End Sub

'دالة قراءة أي ملف وتحويله إلى مصفوفة من البايت حيث يتم إدخال بها مسار الملف
Public Function GetFileBytes(ByVal path As String) As Byte()

    'فرض الملف
    Dim file As Long
    file = FreeFile()
    
    'فرض مصفوفة البايتس التي سيتم قراءة الملف فيها
    Dim bytes() As Byte
    
    If LenB((path)) Then     'التحقق من وجود الملف لتجنب حدوث أخطاء
    
        'فتح الملف لقراءته
        Open path For Binary Access Read As file
        
        'تحديد طول مصفوفة البايتس وهو طول الملف سالب واحد
        'وذلك لأن الترقيم بأي مصفوفة يبدأ من صفر وليس واحد
        ReDim bytes(LOF(file) - 1) As Byte
        
        'قراءة الملف داخل المصفوفة
        Get file, , bytes
        
        'إغلاق الملف بعد الانتهاء من قراءته
        Close lngFileNum
    End If
    
    'إرجاع القيمة المطلوبة كناتج للدالة، وهي مصفوفة البايتس
    GetFileBytes = bytes
End Function