◕ دورة احترافية لربط الإكسل Excel لتحليل البيانات اللحظية والتاريخية ◕ ← إصنع برنامجك

'قص عدد 4 بايت من المصفوفة بداية من الإندكس المحدد وتحويلهم إلى رقم عشري
Public Function ReadSingleIEEE(M() As Byte, ByVal byteIndex As Long) As Single
    Dim bytes(4) As Byte
    Dim i%
    For i = 0 To 3
        bytes(i) = M(byteIndex + i)
    Next i
    ReadSingleIEEE = Bytes4ToSingleIEEE(bytes)
End Function

'تحويل 4 بايت إلى رقم عشري
Public Function Bytes4ToSingleIEEE(M() As Byte) As Single
    Static IEEE_Exp As Byte, IEEE(0 To 3) As Byte
    If M(3) = 0 Then Exit Function
    IEEE_Exp = M(3) - 2
    IEEE(3) = (M(2) And &H80) Or (IEEE_Exp \ 2)
    IEEE(2) = ((CLng(IEEE_Exp) * 128) And &HFF) Or (M(2) And &H7F)
    IEEE(1) = M(1)
    IEEE(0) = M(0)
    Call CopyMemory(Bytes4ToSingleIEEE, IEEE(0), 4)
End Function

#If VBA7 Then
    Private Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
        (Destination As Any, Source As Any, ByVal Length As Long)
#Else
    Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
        (Destination As Any, Source As Any, ByVal Length As Long)
#End If

Public Type Candle
    DATE As Date
    OPEN As Single
    HIGH As Single
    LOW As Single
    CLOSE As Single
    VOLUME As Single
End Type

'قراءة ملف الأسعار وتحويله إلى مصفوفة من الشموع
Public Function ReadDatFile(ByVal path As String, ByVal step As Integer) As Candle()
    
    On Error GoTo error1:           'يمكن أن يحدث خطأ بسبب عدم تواجد الملف أو حجمه صفر
    
    Dim bytes() As Byte
    bytes = GetFileBytes(path)      'قراءة ملف الأسعار إلى مصفوفة من بايتس

    Dim candles() As Candle
    ReDim candles(UBound(bytes) / step - 2) As Candle   'فرض مصفوفة الشموع
    
    Dim deltaDate As Integer    'عدد البايتس الخاصة بالتاريخ
    If step = 28 Then
        deltaDate = 1 * 4
    Else
        deltaDate = 2 * 4
    End If
    
    Dim i As Long
    For i = 1 To UBound(bytes) / step - 1
        
        'قراءة عدد 4 بايت الأولى وهي التاريخ سنة وشهر ويوم
        Dim datePart As Single
        datePart = ReadSingleIEEE(bytes, i * step)
        
        If step = 28 Then
            candles(i - 1).DATE = DateSerial(1900 + (datePart / 10000), _
                (datePart Mod 10000) / 100, datePart Mod 100)   'تحويل الرقم إلى تاريخ
        Else
            'في حالة الشموع أقل من اليومية يتم قراءة الزمن ساعة ودقيقة وثانية
            Dim timePart As Single
            timePart = ReadSingleIEEE(bytes, i * step + 1 * 4)
            'هنا يتم تحويل الرقم الخاص بالتاريخ إلى تاريخ والرقم الخاص بالزمن إلى زمن ثم الجمع
            candles(i - 1).DATE = DateSerial(1900 + (datePart / 10000), _
                (datePart Mod 10000) / 100, datePart Mod 100) + _
                TimeSerial(timePart / 10000, (timePart Mod 10000) / 100, timePart Mod 100)
        End If
        
        'قراءة بيانات الافتتاح والأعلى والأدنى والإغلاق والحجم
        candles(i - 1).OPEN = ReadSingleIEEE(bytes, i * step + deltaDate)
        candles(i - 1).HIGH = ReadSingleIEEE(bytes, i * step + 1 * 4 + deltaDate)
        candles(i - 1).LOW = ReadSingleIEEE(bytes, i * step + 2 * 4 + deltaDate)
        candles(i - 1).CLOSE = ReadSingleIEEE(bytes, i * step + 3 * 4 + deltaDate)
        candles(i - 1).VOLUME = ReadSingleIEEE(bytes, i * step + 4 * 4 + deltaDate)
    Next i
    ReadDatFile = candles
error1:
End Function

'قراءة مصفوفة الشموع
        Dim candles() As Candle
        candles = ReadDatFile(Cells(i + 1, 3), step)    'باستخدام المسار والخطوة
        
        On Error Resume Next        'يحتمل الخطأ في حالة عدم تواجد الملف أو حجمه يساوي صفر
        If UBound(candles) > 0 Then
            Cells(i + 1, 4) = candles(UBound(candles)).CLOSE    'عرض سعر الإغلاق
            
            Cells(i + 1, 5) = ((candles(UBound(candles)).CLOSE - candles(UBound(candles) - 1).CLOSE) / _
                candles(UBound(candles) - 1).CLOSE)             'عرض التغير اليومي
            If Cells(i + 1, 5) < 0 Then
                Cells(i + 1, 5).Font.Color = RGB(160, 0, 0)     'إظهار التغير بالأحمر إذا كان أصغر من صفر
            End If
            
            Cells(i + 1, 6) = candles(UBound(candles)).DATE     'عرض تاريخ آخر شمعة
        End If